Arbeitszeit in Excel berechnen

Wie Excel Uhrzeiten speichert

Excel speichert eine Uhrzeit als Bruchteil eines Tages: 12:00 ist 0,5, 6:00 ist 0,25, eine Minute ist 1/1440. Daraus folgen die drei Regeln, auf denen alle Formeln unten beruhen:

• Eine Zeitdifferenz ist ebenfalls ein Tagesbruchteil – mal 24 ergibt Stunden, mal 1440 Minuten.
• Negative Zeiten kann Excel im Standard-Datumssystem nicht als Uhrzeit anzeigen (es erscheint #####).
• Summen über 24 Stunden brauchen das Format [h]:mm, sonst „springt“ die Anzeige nach 23:59 wieder auf 0:00.

Aufbau der Tabelle

Die Formeln

1. Netto-Arbeitszeit (auch über Mitternacht)

E2:  =REST(C2-B2;1)-D2

C2-B2 wäre bei einer Nachtschicht von 22:00 bis 6:00 negativ. REST(…;1) addiert in diesem Fall einen ganzen Tag: REST(0,25 − 0,9167; 1) = 0,3333 = 8:00 h. Für Beispielzeile 2 ergibt die Formel 16:30 − 7:45 − 0:45 = 8:00.

2. Pause in Minuten statt als Uhrzeit

Wenn Sie die Pause lieber als Zahl (z. B. 45) eintragen:

E2:  =REST(C2-B2;1)-D2/1440

3. Dezimalstunden für die Lohnabrechnung

F2:  =RUNDEN(E2*24;2)

Das Ergebnis 8,00 können Sie direkt mit dem Stundenlohn multiplizieren: =F2*18,50. Die Zelle F muss als Zahl formatiert sein, nicht als Uhrzeit – sonst zeigt Excel „00:00“.

4. Wochen- oder Monatssumme

E9:  =SUMME(E2:E8)      Format [h]:mm  → z. B. 41:15
F9:  =SUMME(F2:F8)      Format Zahl    → 41,25

Summieren Sie für die Dezimalsumme möglichst die ungerundeten Werte (=SUMME(E2:E8)*24), damit sich Rundungsdifferenzen der Einzeltage nicht aufaddieren.

5. Über- und Minusstunden

Mit der Soll-Zeit in Zelle H1 (z. B. 8:00):

G2:  =(E2-$H$1)*24

Rechnen Sie Differenzen in Dezimalstunden. So umgehen Sie das #####-Problem bei negativen Zeiten. Alternativ lässt sich unter Datei › Optionen › Erweitert › „1904-Datumswerte verwenden“ ein Datumssystem aktivieren, das negative Zeiten darstellt – das verschiebt aber alle Datumswerte in der Arbeitsmappe um vier Jahre und ist deshalb riskant.

6. Gesetzliche Mindestpause automatisch

Diese Formel berechnet die kleinste Pause in Minuten, die bei einer Anwesenheit von Beginn bis Ende nach § 4 ArbZG genügt – einschließlich der Grenzfälle knapp über 6 und 9 Stunden (Herleitung in der Methodik):

H2:  =LET(g;REST(C2-B2;1)*1440;
      WENN(g<=360;0;WENN(g<375;15;WENN(g<=390;g-360;
      WENN(g<=570;30;WENN(g<585;g-540;45))))))

LET gibt es ab Excel 2021 bzw. Microsoft 365. In älteren Versionen ersetzen Sie jedes g durch REST(C2-B2;1)*1440. Die vereinfachte Faustregel „ab 6 Stunden Anwesenheit 30 Minuten, ab 9,5 Stunden 45 Minuten“ wäre:

H2:  =WENN(REST(C2-B2;1)*24>9,5;45;WENN(REST(C2-B2;1)*24>6;30;0))

Die Faustregel setzt nie zu wenig Pause an, in manchen Fällen aber mehr als nötig (bei 6:10 h Anwesenheit 30 statt 15 Minuten) – und verkürzt damit die erfasste Arbeitszeit.

7. Stunden in der Nachtzeit (23–6 Uhr)

Für eine Schicht, die höchstens einmal über Mitternacht geht:

I2:  =LET(s;B2;e;B2+REST(C2-B2;1);
      (MAX(0;MIN(e;1+6/24)-MAX(s;23/24))
      +MAX(0;MIN(e;6/24)-s))*24)

Beispiel: 22:00 bis 6:00 ergibt 7,00 Stunden in der Nachtzeit. Die Formel betrachtet die Anwesenheit; Pausen in der Nacht müssen Sie gegebenenfalls abziehen.

Häufige Fehler

• Ergebnis 0:00 bei Summen: Format auf [h]:mm umstellen.
• #####: negative Zeit – Formel mit *24 in Dezimal umstellen oder REST verwenden.
• Uhrzeit als Text: Wurde „7.45“ statt „7:45“ eingegeben, ist es eine Zahl bzw. Text. Prüfen mit =ISTZAHL(B2); Uhrzeiten sind Zahlen kleiner als 1.
• Semikolon oder Komma: Deutsches Excel trennt Argumente mit Semikolon. In englischen Versionen heißen die Funktionen MOD, IF, SUM, ROUND, und das Trennzeichen ist ein Komma.

Excel-Tabelle oder Zeiterfassung?

Für die private Kontrolle der eigenen Stunden reicht Excel. Einen fertigen Monatsbogen mit Feiertagen bietet der Stundenzettel online. Für Arbeitgeber gilt seit dem BAG-Beschluss vom 13.09.2022 die Pflicht, die Arbeitszeit zu erfassen (siehe Zeiterfassungspflicht). Die Form ist gesetzlich (noch) nicht vorgeschrieben, eine Tabelle ist also nicht per se unzulässig. Sie muss aber die tatsächliche Arbeitszeit verlässlich wiedergeben, Änderungen nachvollziehbar machen und nach § 16 Abs. 2 ArbZG zwei Jahre aufbewahrt werden. Je mehr Beschäftigte, Schichten und Korrekturen es gibt, desto schwerer wird das mit einer offenen Tabelle.

Das Wichtigste in Kürze

• Netto: =REST(Ende-Beginn;1)-Pause
• Dezimal: =Zeit*24, Zelle als Zahl formatieren
• Summen: Format [h]:mm
• Überstunden in Dezimal rechnen, um negative Zeiten zu vermeiden

Quellen

• Microsoft Support: REST-Funktion
• § 4 ArbZG, § 16 ArbZG

Weitere Erklärungen zu Pausen, Höchstarbeitszeit, Überstunden und Zeiterfassung finden Sie gesammelt im Ratgeber Arbeitszeit.